Construct a table on page B with BD data and download on page A by ajax_jquery

Question

I need now in a b.Asp file, build and popular a table(html) and then download by ajax in the a.asp file. So:

b.Asp file

<%@ LANGUAGE="VBSCRIPT" %>
<%    
Option explicit

%> 
<!--#include file="../../gen/inc/EBAXML.inc"-->
<!--include de conexao com banco de dados-->
<!--#include file=..\..\gen\asp\gen0146a.asp-->
<!--#include file=..\..\gen\asp\gen0146b.asp-->
<%

dim oPesquisa
dim rsPesquisa
dim ind_selecionado
dim origem
dim ind_internacao, ind_emergencia, ind_day_hospital
dim sXML, vetPL(1, 4)
dim cod_prestador_ts
dim ind_vinculacao
dim cod_operadora


cod_prestador_ts = Request("cod_prestador_ts")
ind_vinculacao   = Request("ind_vinculacao")
origem           = Request("origem")

'if trim(cod_prestador_ts) <> "" then
    sXML = ""
    sXML = sXML & "<?xml version=""1.0"" encoding=""ISO-8859-1"" ?>" & _
                              "<parametros>"

    sXML = sXML & "<sCodPrestadorTs>" & Request("cod_prestador_ts") & "</sCodPrestadorTs>" &_
                              "<sIndVinculacao>" & Request("ind_vinculacao") & "</sIndVinculacao>"  & _
                              "<sCodOperadora>" & Request("cod_operadora") & "</sCodOperadora>"  & _
                              "</parametros>"


    vetPL(1, 1) = "IN"
    vetPL(1, 2) = "adLongVarChar"
    vetPL(1, 3) = "p_xml_parametros"
    vetPL(1, 4) = sXML

    set rsPesquisa = rsCursorOracle( CStr(Session("ace_usuario")),_
                                 CStr(Session("ace_senha")),_
                                 CStr(Session("ace_ip")),_
                                 CStr(Session("ace_sistema")),_
                                 CStr(Session("ace_modulo")),_
                                 "prs_rcs_gestao.get_prestador_tipo", _
                                 vetPL, _
                                 false )  


    if ucase(origem) = "CONSULTA" then
        Do While Not rsPesquisa.eof

            if IsNull(rsPesquisa("cod_prestador_ts")) then
                ind_selecionado = "N"
            else
                ind_selecionado = "S"
            end if

            if ind_selecionado = "S" then 
                ind_internacao      = lerCampo(rsPesquisa("ind_internacao"))
                ind_emergencia      = lerCampo(rsPesquisa("ind_emergencia"))
                ind_day_hospital    = lerCampo(rsPesquisa("ind_day_hospital"))
            end if 

            rsPesquisa.movenext
        loop   
            '<!--Response.write sRetorno-->
    else
        Do While Not rsPesquisa.eof

            if IsNull(rsPesquisa("cod_prestador_ts")) then
                ind_selecionado = "N"
            else
                ind_selecionado = "S"
            end if

            ind_internacao      = lerCampo(rsPesquisa("ind_internacao"))
            ind_emergencia      = lerCampo(rsPesquisa("ind_emergencia"))
            ind_day_hospital    = lerCampo(rsPesquisa("ind_day_hospital"))

            rsPesquisa.movenext
        loop   

    end if 

    set oPesquisa      = nothing    
    set rsPesquisa     = nothing

'end if 

function lerCampo(campo)
    if isNull(campo) then
        lerCampo = ""
    else
        lerCampo = campo
    end if
end function

function verificaLeitos(internacao, emergencia, day_hospital)

    if internacao = "S" or emergencia = "S" or day_hospital = "S" then
        verificaLeitos = "S"
    else
        verificaLeitos = "N"
    end if

end function

%>

And here is my jquery/ajax function and where it will be downloaded table.

function CarregaTabela() {
       var cod_ts   = '<%= Request.QueryString("cod_prestador_ts")%>';
       var ori      = '<%= Request.QueryString("Origem")%>';
       var ind_vinc = $("#ind_vincul").val();
       var cod_oper = '<%= Request.QueryString("cod_operadora")%>';
       var ind_aut  = '<%= Request.QueryString("ind_autorizacao")%>';

       alert(ind_vinc);

        $.ajax({
            url: 'prs0061b_crossbrowser.asp?cod_prestador_ts=' + cod_ts + '&ind_vinculacao=' + ind_vinc + '&origem=' + ori + '&ind_autorizacao=' + ind_aut + '&cod_operadora_principal=' + cod_oper + '',
            type: 'POST',
            success: function (data) {

                $("divOperadora_<%=iCont %>").html(a_table);//aqui nessa posição será montada a table

            },
            error: function (error) {

                alert(3);
            }
        })
    }

The table will have all fields that come in the variable rsPesquisa, data from Oracle.

Answer 1

I solved so in B.Asp file:

sRetorno = "<table>"
sRetorno = sRetorno & "<thead>"
sRetorno = sRetorno & "<tr>"
sRetorno = sRetorno & "<th>Código</th>"
sRetorno = sRetorno & "<th>Nome</th>"
sRetorno = sRetorno & "<th>Principal ?</th>"
sRetorno = sRetorno & "<th>Divulgação ?</th>"
sRetorno = sRetorno & "<th>Validar primeira Sequência ?</th>"
sRetorno = sRetorno & "<th>leitos</th>"
sRetorno = sRetorno & "<th>Observação</th>"
sRetorno = sRetorno & "<th>Acomodação</th>"
sRetorno = sRetorno & "<th>ind_hospital_geral</th>"
sRetorno = sRetorno & "</tr>"
sRetorno = sRetorno & "</thead>"

sRetorno = sRetorno & "<tbody>"


'if trim(cod_prestador_ts) <> "" then
    sXML = ""
    sXML = sXML & "<?xml version=""1.0"" encoding=""ISO-8859-1"" ?>" & _
                              "<parametros>"

    sXML = sXML & "<sCodPrestadorTs>" & Request("cod_prestador_ts") & "</sCodPrestadorTs>" &_
                              "<sIndVinculacao>" & Request("ind_vinculacao") & "</sIndVinculacao>"  & _
                              "<sCodOperadora>" & Request("cod_operadora") & "</sCodOperadora>"  & _
                              "</parametros>"


    vetPL(1, 1) = "IN"
    vetPL(1, 2) = "adLongVarChar"
    vetPL(1, 3) = "p_xml_parametros"
    vetPL(1, 4) = sXML

    set rsPesquisa = rsCursorOracle( CStr(Session("ace_usuario")),_
                                 CStr(Session("ace_senha")),_
                                 CStr(Session("ace_ip")),_
                                 CStr(Session("ace_sistema")),_
                                 CStr(Session("ace_modulo")),_
                                 "prs_rcs_gestao.get_prestador_tipo", _
                                 vetPL, _
                                 false )  


    if ucase(origem) = "CONSULTA" then
        Do While Not rsPesquisa.eof

            if IsNull(rsPesquisa("cod_prestador_ts")) then
                ind_selecionado = "N"
            else
                ind_selecionado = "S"
            end if

            if ind_selecionado = "S" then 
                ind_internacao      = lerCampo(rsPesquisa("ind_internacao"))
                ind_emergencia      = lerCampo(rsPesquisa("ind_emergencia"))
                ind_day_hospital    = lerCampo(rsPesquisa("ind_day_hospital"))
            end if

                sRetorno = sRetorno & "<tr>"
                sRetorno = sRetorno & "<td>"&rsPesquisa("cod_tipo_prestador")&"</td>" 
                sRetorno = sRetorno & "<td>"&rsPesquisa("nome_tipo_prestador")&"</td>" 
                sRetorno = sRetorno & "<td>"&ind_selecionado&"</td>" 
                sRetorno = sRetorno & "<td>"&ind_selecionado&"</td>" 
                sRetorno = sRetorno & "<td>"&rsPesquisa("ind_principal")&"</td>" 
                sRetorno = sRetorno & "<td>"&rsPesquisa("ind_divulgacao")&"</td>" 
                sRetorno = sRetorno & "<td>"&verificaLeitos(ind_internacao, ind_emergencia, ind_day_hospital)&"</td>" 
                sRetorno = sRetorno & "<td>"&rsPesquisa("txt_obs_nao_divulgacao")&"</td>" 
                sRetorno = sRetorno & "<td>"&rsPesquisa("ind_tipo_acomodacao")&"</td>" 

                sRetorno = sRetorno & "</tr>"

            rsPesquisa.movenext
        loop   

            sRetorno = sRetorno & "</tbody>"
            sRetorno = sRetorno & "</table>"
            Response.write sRetorno
    else
        Do While Not rsPesquisa.eof

            if IsNull(rsPesquisa("cod_prestador_ts")) then
                ind_selecionado = "N"
            else
                ind_selecionado = "S"
            end if

            ind_internacao      = lerCampo(rsPesquisa("ind_internacao"))
            ind_emergencia      = lerCampo(rsPesquisa("ind_emergencia"))
            ind_day_hospital    = lerCampo(rsPesquisa("ind_day_hospital"))

                sRetorno = sRetorno & "<tr>"
                sRetorno = sRetorno & "<td>"&rsPesquisa("cod_tipo_prestador")&"</td>" 
                sRetorno = sRetorno & "<td>"&rsPesquisa("nome_tipo_prestador")&"</td>" 

                sRetorno = sRetorno & "</tr>"

            rsPesquisa.movenext
        loop   

        sRetorno = sRetorno & "</tbody>"
        sRetorno = sRetorno & "</table>"
        Response.write sRetorno

    end if 

And in File A.Asp I made this call like this: create a div that will receive the result from B.Asp

<div id="testeRetorno"></div>

Here I call via ajax:

function CarregaTabela() {
       var cod_ts   = '<%= Request.QueryString("cod_prestador_ts")%>';
       var ori      = '<%= Request.QueryString("Origem")%>';
       var ind_vinc = $("#ind_vincul").val();
       var cod_oper = '<%= Request.QueryString("cod_operadora")%>';
       var ind_aut  = '<%= Request.QueryString("ind_autorizacao")%>';
        $.ajax({
            url: 'prs0061b_crossbrowser.asp?cod_prestador_ts=' + cod_ts + '&ind_vinculacao=' + ind_vinc + '&origem=' + ori + '&ind_autorizacao=' + ind_aut + '&cod_operadora_principal=' + cod_oper + '',
            type: 'POST',
            success: function (data) {

                $('#testeRetorno').html(data);

            },
            error: function (error) {
            }
        })
    }