Help with logic - Portugol Studio

Question

good morning! I’m trying to learn how to program, I started with logic + portugol. When trying to perform a condition exercise, the following error occurred in portugol studio:

"There are code snippets where the methodName variable may not have been started"

   programa
{
    funcao inicio()
    {
        
        cadeia nome, nomeMaior, nomeMenor
        inteiro idade, cont
        inteiro idadeMaior = 0
        inteiro idadeMenor = 999
        real soma = 0.0
        real media = 0.0
        
        para (cont = 0; cont < 10; cont++) {
            escreva("Nome: ")
            leia(nome)

            escreva("Idade: ")
            leia(idade)

            se (idade < idadeMenor) {
                idadeMenor = idade
                nomeMenor = nome
            }

            se (idade > idadeMaior) {
                idadeMaior = idade
                nomeMaior = nome
            }

            soma = soma + idade
        }

        media = soma / 10
        escreva("A média de idades é: ", media, "\n")
        escreva(nomeMenor , " tem a menor idade que é: ", idadeMenor , " anos.\n")
        escreva(nomeMaior , " tem a maior idade que é: ", idadeMaior , " anos.\n")
    }
}

Thank you in advance.

Answer 1

I took care of it! Due to the new versions of Portugol Studio, the same is asking that values be assigned to variables.

For example:

cadeia nome = ""
inteiro idade = 0
real preco = 0.0 

Answer 2

Anderson, you cannot use a variable that has not been initialized, because the variable is expected to have a value to be used, and since it was not initialized, it does not contain any value. Since you only set a value for the variable nameMenor inside the to but used the variable outside the to, you had to ensure that the variable was initialized