Return only positive results

Question

I’m doing an exercise in visualg, in which the result can be both negative and positive, only I want the results only positive and not negative. How do I get it? What I have so far:

algoritmo "semnome"
// Função :
// Autor :
// Data : 03/01/2018
// Seção de Declarações 
var
   time1,time2,dife:inteiro

inicio
      escreva("quantos gols do time A? ")
      leia(time1)
      escreva("quantos gols do time B? ")
      leia(time2)
      dife <- (time1 - time2)
      as <- (dife p ou q)
      se (dife >=1) e (dife <=3)
        escreva("partida normal", dife)
      senao
           se (dife =0) entao
             escreva(normal)
           FimSe
      FimSe
fimalgoritmo

Answer 1

Use a conditional before subtracting the values of the variable time1 and time2:

se (time1 >= 0) e (time2 >= 0) entao
   /* Restante do código */
fimse

It’s been years since I’ve used the Portugol, maybe I’ve changed something, but the logic is the same.

Answer 2

Hello try to do so (need to compare which is the biggest before making a difference):

algoritmo "exercicios"
var
time1,time2,dife:inteiro

  inicio
  escreva("quantos gols do time A? ")
  leia(time1)
  escreva("quantos gols do time B? ")
  leia(time2)
  se time1>=0 e time2>=0 entao
  se time1>time2 entao
  dife <- (time1 - time2)
  fimse
  fimse
  se time1>=0 e time2>=0 entao
  se time2>time1 entao
  dife<- time2-time1
  fimse
  fimse
  as <- (dife p ou q)
  se (dife >=1) e (dife <=3)
    escreva("partida normal", dife)
  senao
       se (dife =0) entao
         escreva(normal)
       fimse
   fimse
   fimalgoritmo

Answer 3

I did it and it worked:

Algoritmo "ex003_condicionais"
// Disciplina   : Algoritmos - Curso em Vídeo
// Professor   : Gustavo Guanabara
// Descrição   : Exercícios de estruturas condicionais
// Autor(a)    : Douglas Oliviera
// Data atual  : 31/12/2020
Var
   ban, mad, dif : inteiro

Inicio
      escreval ("       BANGU X MADUREIRA        ")
      escreval ("--------------------------------")
      escreva ("Quantos gols do BANGU? ")
      leia (ban)
      escreva ("Quantos gols do MADUREIRA? ")
      leia (mad)

      se (ban > mad) entao
         dif <- ban - mad
      senao
           dif <- mad - ban
      fimse

      escolha dif
              caso 0
                   escreval ("---------------------------")
                   escreval (" DIFERENCA: ", dif)
                   escreval (" STATUS: EMPATE")
                   escreval ("---------------------------")

              caso 1, 2, 3
                   escreval ("---------------------------")
                   escreval (" DIFERENCA: ", dif)
                   escreval (" STATUS: PARTIDA NORMAL")
                   escreval ("---------------------------")
              outrocaso
                       escreval ("---------------------------")
                       escreval (" DIFERENCA: ", dif)
                       escreval (" STATUS: GOLEADA")
                       escreval ("---------------------------")
      fimescolha


Fimalgoritmo

Answer 4

You can use the function Abs that returns an Absolute number, that is, always positive.

Here’s a practical example:

    algoritmo "BANGUxMADUREIRA"
    // Data : 29/05/2021
    // Seção de Declarações
    var
    ban, mad, dif: Inteiro
    
    inicio
    // Seção de Comandos
    escreval(" BANGU x MADUREIRA ")
    escreval("-------------------------------")
    escreva("QUANTOS GOLS DO BANGU? ")
    leia(ban)
    escreva("QUANTOS GOLS DO MADUREIRA? ")
    leia(mad)
    escreval("-------------------------------")
    dif <- abs(ban - mad)
    se (dif = 0) entao
       escreval(" DFERENÇA: ", dif)
       escreval(" STATUS: JOGO EMPATADO!")
       escreval("-------------------------------")
    senao
       se (dif = 1) entao
          escreval(" DFERENÇA: ", dif)
          escreval(" STATUS: JOGO ACIRRADO!")
          escreval("-------------------------------")
       senao
          se (dif >= 2) entao
             escreval(" DFERENÇA: ", dif)
             escreval(" STATUS: GOLEADA!")
             escreval("-------------------------------")
          senao
          fimse
       fimse
    fimse
    fimalgoritmo