Develop PDF417 with Delphi

Question

Good afternoon.
I use an old report generator for Delphi XE7 (pReport). I have the source code of it, and I’ve already made many changes to it. Now one more challenge, I need to include a new type of Barcode in the generator. It would be the PDF417.
Does anyone have any idea how to do that?

From what I saw in the report generator project, it uses the Vgr_barcode, which would be a free but no longer maintained library. This library was made by Andreas Schmidt but when generating 2D barcodes, the library has been discontinued. Does anyone use this library? If so, it has already evolved?
I hope I was specific in the question.

Answer 1

Taking into account that just add the functionality of generating the barcode and format PDF417 with the "Pdf417lib", follows toturial:

No need to install dpk that comes along, unless you want to implement something in design time.

First step is to add in the project’s search path ( Ctrl+Shift+F11 ) the following directories:

...\pas417lib-master\vcl
...\pas417lib-master\src

Now follow the code of the implemented classes:

Barcodegenerator - Interface

unit BarcodeGenerator;

interface

uses
  Graphics;

type
  IBarcodeGenerator = interface
    ['{BDBF2DC5-29CB-413F-9920-579D4213B638}']

    function GetPdf417(AValue: String): TBitmap;    
  end;

implementation

end.

Barcodegeneratorimpl - Implementation

unit BarcodeGeneratorImpl;

interface

uses
  Graphics, PDF417Barcode, BarcodeGenerator;

type
  TBarcodeGeneratorImpl = class(TInterfacedObject, IBarcodeGenerator)

  private
    MyCodeBar: TPDF417BarcodeVCL;

  public
    constructor Create;
    destructor Destroy; override;   
    function GetPdf417(AValue: String): TBitmap;   
  end;

implementation

uses
  SysUtils;

{ THelperBarcodeGenerator }

constructor TBarcodeGeneratorImpl.Create;
begin
  MyCodeBar := TPDF417BarcodeVCL.Create(nil);
end;

destructor TBarcodeGeneratorImpl.Destroy;
begin
  FreeAndNil(MyCodeBar);
  inherited;
end;

function TBarcodeGeneratorImpl.GetPdf417(AValue: String): TBitmap;
begin
  MyCodeBar.Lines.Add(AValue);
  Result := MyCodeBar.Bitmap;
end;

end.

Now in this example, a normal Unit was created, with the visual part, a Tedit, a Timage and a Tbutton were added.

Example of use

unit Unit2;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
   Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls, Vcl.StdCtrls;

type
  TForm2 = class(TForm)
    Edit1: TEdit;
    Button1: TButton;
    Image1: TImage;
    procedure Button1Click(Sender: TObject);    
  end;

var
  Form2: TForm2;

implementation

uses
  BarcodeGenerator, BarcodeGeneratorImpl;

{$R *.dfm}

procedure TForm2.Button1Click(Sender: TObject);
var
  FBarcodeGenerator: IBarcodeGenerator;
begin    
  FBarcodeGenerator     := TBarcodeGeneratorImpl.Create;
  Image1.Picture.Bitmap := FBarcodeGenerator.GetPdf417(Edit1.Text);   
end;

end.

I believe that with the 2 Barcodegenerator and Barcodegeneratorimpl Units, it is easy to inject this function into your framework.